» » » mIRC Hazır Kodlar Arşiv

mIRC Hazır Kodlar Arşiv

mIRC Hazır Kodlar

Bu başlık altında tüm kısa mIRC Hazır Kodlar tek başlık altında toplanıp sizlere sunulmuştur.

İşinize yarayacak parça kodlar ve açıkalamaları sırasıyla vereceğim.

alias gir set %jp join | .enable #x | list
alias cık set %jp part | .enable #x | list
#x off
raw *:*:{
  if ($regex($numeric,^(32[2-3])$)) { 
    var %: = $regml(1) 
    $iif(%: == 322,$iif(%jp == join,%jp $2,$iif(!$regex($2,/^(#operhelp|#help)$/i),%jp $2)),$iif(%: == 323,.disable #x))
  }
}
#x end
Bu kod /gir şeklinde uygulandığında list-de çıkan tüm kanallara girmenize, /cık şeklinde uygulandığında #operhelp ve #help kanalları haric tüm kanallardan çıkmanıza yarar.


alias mjoin {
  if ($regex($1,/^#(\w)/i) && $regex($2,/^#(\w)/i)) {
    var %1 = 1,%2 = $iif($iif($nick($1,0) >= $3,$3),$3,$nick($1,0)) 
    while (%1 <= %2) { 
      $iif($nick($1,%1) !ison $2,sajoin $nick($1,%1) $2) 
      inc %1 
    } 
  } 
  else echo $color(info) -eat * /mjoin: Hatalı kullanım: /mjoin #INchan #OUTchan <number>
}
Bu kod bir kanaldan diğer bir kanala belirtilen sayıdaki kullanıcı taşımak için kullanılır. Gayet gelişmiş bir koddur. 
Kullanım şekli: /mjoin #aktarılacak-kanal #aktarılan-kanal <kullanıcı-sayısı> 
Not: <kullanıcı-sayısı> kısmı boş veya sallamasyon bir sayı yazılırsa tüm userları çekcektir.


on *:start: {
  if (!$window(@bilgi)) window -ak0 @bilgi
  var %e = echo 4 @bilgi,%c = $+($chr(3),1),%s = $token($readini($nopath($mircini),mIRC,host),2,58) 
  %e Server: %c $+ %s
  %e Aktif $+(nick,:,%c,$chr(32),$iif($me,$v1,Girilmemiş.))
  %e Yedek $+(nick,:,%c,$chr(32),$iif($anick,$v1,Girilmemiş.))
  %e IP $+(adresi,:,%c,$chr(32),$ip)
  %e $+(Tarih/saat,:,%c,$chr(32),$date - $time)
}
Bu kod scriptizi açtığınızda @bilgi penceresinde nick, yedek nick, IP adresi vb. bilgilerinizi görmenize olanak sağlar.


on *:snotice:*client connect*:{
  var %1 = 1 
  while ($read(bad.txt,%1)) { 
    if ($regex($9,/ $+ $v1 $+ /i)) { 
      inc %* 1 
      os raw svsnick $9 $+(user,%*,$r(0,999)) 0:0 
      break 
    } 
    inc %1
  }
}
Bu kod sunucuya giren kullanıcılara bad.txt dosyası içerisindeki kelimeleri tarayarak badnick kontolü yaparak, bulunan badnick'in rumuzunu user[random-sayı] şeklinde değiştirir. 
Not: Bu kodu kullanabilmek için /os raw svsnick komutunu kullanabilmeniz gerekmektedir.


alias allkick { 
  if ($1) { 
    var %1 = 1 
    while (%1 <= $comchan($1,0)) { 
      if ($regex($nick($comchan($1,%1),$me).pnick,@|&|~|%) || $regex($usermode,A|a|N|C)) { 
        cs akick $comchan($1,%1) add $address($1,2) $2- 
        cs akick $comchan($1,%1) enforce 
      } 
      inc %1 
    } 
    var %2 %1 - 1 
    echo -at %2 kanalda akick uyguladınız.
  } 
}
Bu kod belirlediğiniz nicki ortak tüm kanallardan akick-e almanızı sağlar. 
Kullanım şekli: /allkick <nick> <akick sebebi>


on !*:kick:#kanal: {
  hinc -m kick $nick 1 
  hsave -i kick kick.hsh 
  write kick.txt Saat: $time - Kick atan: $nick - Kicklenen: $knick - Sebeb: $1-
}
on *:text:*:#kanal: {
  if ($regex($1,/^!kick$/i) && $nick isreg #) {
    if ($hget(kick,$nick)) msg # Attığınız kick sayısı: $v1
    else msg # Kick uygulamamışsınız.
  }
  if ($regex($1,^!list$)) {
    var %1 = 1 
    while (%1 <= $lines(kick.txt)) { 
      msg # $read(kick.txt,%1) 
      inc %1 
    } 
  }
}
on *:start:{ 
  if ($isfile(kick.hsh)) { 
    hmake kick 50 
    hload -i kick kick.hsh 
  }
}
Bu kod belirtilen #kanal'da atılan kick'leri detaylı bir şekilde kick.txt dosyasına kaydeder ve yine belirtilen kanalda !kick komutunu uygulayan nicke ait bir kick-list kaydı varsa bu listeyi sıralar. 
Kullanım şekli: !kick


chk { 
  var %1 = 1 
  while (%1 <= $hget(bad,0).item) { 
    if ($ialchan($+(*,$hget(bad,%1).item,*),$1,0) == 1 && >= 0) {
      hadd -m $1 $ialchan($+(*,$hget(bad,%1).item,*),$1,1).nick 1
    }
    else { 
      chk2 $1 $+(*,$hget(bad,%1).item,*) 
    } 
    inc %1 
  }
  echo $colour(info) $1 $timestamp $iif($hget($1,0).item >= 1,Bulunan badnick sayısı: $hget($1,0).item,Badnick bulunamadı.)
  echo $colour(info) $1 $timestamp Nickleri görüntülemek için: CTRL + F9 tuşuna basınız.
  echo $colour(info) $1 $timestamp $iif($regex($nick($1,$me).pnick,@|&|%|~),$iif($regex($usermode,a|A|N|C),Nickleri kanal'dan atmak için: F9 tuşuna basınız.),Kanaldan atma yetkiniz yok.))
} 
chk2 {
  if ($1 && $2) { 
    var %& = 1 
    while (%& <= $ialchan($2,$1,0)) { 
      hadd -m $1 $ialchan($2,$1,%&).nick 
      inc %&
    }
  }
}
cF9 {
  if ($hget($active)) seen $active 
}
seen { 
  var %t = 1,%tt 
  while (%t <= $hget($1,0).item) { 
    %tt = $addtok(%tt,$hget($1,%t).item,32) 
    inc %t 
  } 
  echo $colour(info) $1 $timestamp Tespit edilen badnickler: %tt 
}
F9 { 
  if ($hget($active)) bans $active  
  else diğer komut 
}
bans {
  var %- = 1 
  while (%- <= $hget($1,0).item) { 
    ban -k $1 $hget($1,%-).item 2 SEBEB. 
    inc %- 
  } 
  %// = %- - 1 
  echo $colour(info) $1 $timestamp Atılan nick sayısı: %// 
  hfree $1
}
badd { 
  $iif(!$1,echo -at Kelime girmediniz.,$iif($hget(bad,$1),echo -at $1 kelimesi listede.,hadd -m bad $1 1)) 
  hsave -i bad bad.hsh
}
bdel { 
  $iif(!$1,echo -at Kelime girmediniz.,$iif(!$hget(bad,$1),echo -at $1 kelimesi listede değil.,hdel bad $1)) 
  hsave -i bad bad.hsh
}
blist {
  window -Caldk0 +L @Bad-words 0 0 200 400 
  var %- = 1 
  while (%- <= $hget(bad,0).item) { 
    aline @bad-words $+(%-,-) $hget(bad,%-).item 
    inc %-
  }
}
on me:*:join:#:.ial on | who # | .timer 1 2 chk #
on *:start: {
  if ($isfile(bad.hsh)) { 
    hmake bad 50 
    hload -i bad bad.hsh 
  }
}
Badnick Tarama Kodu  

Kod neler yapar? 

- Herhangi bir kanala girdiğiniz-de "bad" tablosuna eklemiş olduğunuz ve badnick niteliği taşıyan kelimeleri kanaldaki tüm kullanıcılarda arar. 
- Bulunan sonuçları size /echo mesajı ile gösterir. 
- Tarama sonunda f9 tuşuna basarsanız son taramaya yakalanan tüm nickleri kanaldan uzaklaştırır. 
/badd <kelime> şeklinde badnick listesine kelime ekleyebilirsiniz. 
/bdel <kelime> şeklinde badnick listesinden belirtilen kelimeyi silebilirsiniz. 
/blist komutunu kullanarak listeyi görebilirsiniz. 
CTRL + f9 kombinasyonunu kullanarak tespit edilen badnickleri görebilirsiniz. 

Not: Kodları (aliases - ALT + D) kısmına ekleyiniz.


alias users {
  if ($active ischan) { 
    var %s = 1,%n 
    while ($nick($active,%s)) {
      %n = $addtok(%n,$v1,32) 
      inc %s 
    } 
    say $remove(%n,$me) $1- 
  } 
}
Bu kod kanaldaki herkeze seslenmek için kullanılır. Kodu kullanmak için herhangi bir kanal penceresinde; /users <mesaj> yapabilirsiniz.


on ^*:open:?:*:{
  if (%closed) { 
    inc $+(%,rumuz,$nick) 1 
    if ($($+(%,rumuz,$nick),2) = 1) { 
      msg $nick Özelim kapalıdır. Yazdıklarınız bana ulaşmamakta.
    } 
    return
  } 
}
menu channel,status,query {
  Özel aç/kapa
  .Özeli kapat:set %closed 1 | echo -ea -: Özeliniz konuşmaya kapatıldı. 
  .Özeli aç:unset %closed %*rumuz* | echo -ea -: Özeliniz konuşmaya açıldı.
}
Bu kod özelinizi açmaya/kapatmaya ve karşı kullanıcıya geri-bildirim yapmanıza olanak sağlar.



on !^*:join:#: {
  hadd -m # $nick $site 
  hsave -i # # $+ .chans
  if ($hfind(#,$site,0).data >= 2) { 
    var %s = 1,%q 
    while (%s <= $hfind(#,$site,0).data) {
      %q = $addtok(%q,$hfind(#,$site,%s).data,32) 
      inc %s 
    } 
    echo $color(join) # * Giriş: $nick $+($chr(40),$remove($address($nick,0),*,!),$chr(41)) $&
      - Önceki nickleri: $+($chr(40),$remove(%q,$nick),$chr(41)) 
    return
  }
}
on *:start:noop $findfile($mircdir,*.chans,0,.timer 1 0 hmake $token($nopath($1-),1,46) $(|,) hload -i $token($nopath($1-),1,46) $nopath($1-))
Bu kod kanala giriş yapan kullanıcının varsa daha önceki nicklerini giriş bilgisinde gösterir. 
Not: Tüm veriler HD'ye kaydolur ve açılışta yükletilir.


on *:text:!bilgi * &:#:.enable #n | ns auth $2 
#n off
on *:notice:*:?:{ 
  if ($nick == nickserv) { 
    msg #kanal $1- 
    .disable #n 
  }
}
#n end
Bu kod !bilgi nick olarak kullanıldığı zaman, kişinin auth-code bilgisini belirlediğiniz #kanal'a yansıtır.



on *:connect:.timer 0 1800 idlekntrl 1800
alias idlekntrl { 
  if ($idle >= $1 && !$away) {
    away AWAY-MESAJIN. 
  }
}
Bu kod 30 dakikada bir kendinize idle kontrolu yaparak, eğer idle süresi belirtilen süreyi (saniye cinsinden) geçmişse /away konumuna otomatik geçmenize yarar.



alias -l days return $replacecs($1,Monday,Pazartesi,Tuesday,Salı,Wednesday,Çarşamba,Thursday,Perşembe,Friday,Cuma,Saturday,Cumartesi,Sunday,Pazar)
alias -l idl return $replace($1-,Secs,$+($chr(32),Saniye),Sec,$+($chr(32),Saniye),Mins,$+($chr(32),Dakika),Min,$+($chr(32),Dakika),Hrs,$+($chr(32),Saat),Hr,$+($chr(32),Saat),Days,$+($chr(32),Gün),Day,$+($chr(32),Gün),Wks,$+($chr(32),Hafta),Wk,$+($chr(32),Hafta))
alias -l cnnt return $idl($duration($calc($ctime - $1)))
raw 317:*: { 
  echo -a * Bağlanış: $days($asctime($4,$+($chr(40),dddd,$chr(41) dd/mm/yyyy,) - HH:nn:ss))
  echo -a * Konuşmadığı süre: $idl($duration($3))
  echo -a * Bağlı olduğu: $cnnt($4) | haltdef
}
Bu kod kişiye whois çektiğinizde kişinin "bağlantı süresini, konuşmadığı süreyi, bağlantı zamanını" türkçe ve düzenli olarak gösterilmesine yarar.


alias slist .enable #r | who
#r off
raw *:*: {
  haltdef
  if ($numeric = 352) { 
    $iif(!$window(@slist),window -Cak0dl +L @slist 0 0 200 300) 
    if ($chr(35) !isin $2) { 
      inc %1 
      aline 5 @slist $+(%1,-,$6)) 
    } 
  }
  if ($numeric = 315) { 
    if ($window(@slist)) { 
      aline @slist $chr(160) 
      aline @slist Toplam: $+($chr(2),%1,$chr(2)) adet kullanıcı. 
    } 
    unset %1 
    .disable #r 
  }
}
#r end
Bu kod statusde bulunan nickleri ayrı bir pencerede(@slist) listemek ve işlevler yapmak için kullanılır. Kodu kullanmak için /slist yapmanız yeterlidir.



on *:snotice:*: {
  if (*client connect* iswm $1-) { 
    var %n = $+(",$9,"),%i = $remove($gettok($10,1,64),$chr(40)),%ip = $remove($gettok($10,2,64),$chr(41)) 
    $iif(!$window(@giriş/çıkış),window -nCk0 @giriş/çıkış) 
    echo -te @giriş/çıkış => Giriş: $replacecs(%n,",$+($chr(3),0,",$chr(3))) ! %i @ %ip 
  }
  if (*client exiting* iswm $1-) { 
    var %nn = $+(",$6,"),%ii = $remove($gettok($7,1,64),$chr(40)),%ipp = $remove($gettok($7,2,64),$chr(41)) 
    $iif(!$window(@giriş/çıkış),window -nCk0 @giriş/çıkış) 
    echo -te @giriş/çıkış <= Çıkış: $replacecs(%nn,",$+($chr(3),0,",$chr(3))) ! %ii @ %ipp 
  }
}
on ^*:hotlink:"*":@giriş/çıkış:return
on *:hotlink:*:@giriş/çıkış:gline $remove($1,") :sebeb.
Bu kod sunucuya giren/çıkan kullanıcıları ayrı bir pencerede (@giriş/çıkış) gösterir ve nicklerin üzerine tıkladığında sunucudan uzaklaştırmanıza yarar.


on !*:join:#:{ 
  if ($regex($nick(#,$me).pnick,@|&|~|%|(\+))) { 
    hadd -mu5 # $+(#,½,$nick) 1 
    if ($hget(#,0).item >= 4) {
      mode # +MR 
      msg # Kanal modları değişti vs. 
      var %1 = $v1,%2 = 1 
      while (%2 <= %1) { 
        ban -k # $removecs($hget(#,%2).item,#,½) 2 BAN SEBEBİ.
        inc %2 
      } 
    }
  }
}
Bu kod kanala 5 saniye içerisinde 4 veya fazlası giriş yapıldığında, giren tüm nickleri kanaldan banlar ve kanalın modlarını +RM yapar.



on *:text:!at* &:#: { 
  if ($regex($nick,/^(nick1|nick2|nick3)$/i)) { 
    var %s = 1,%q = $comchan($2,0) 
    while (%s <= %q) { 
      ban -k $comchan($2,%s) $2 BAN SEBEBİ.
      inc %s 
    } 
  }
}
Bu kod kanalda belirtilen nicklerden herhangi birisi (nick1, nick2 ve ya nick3) !at nick yaptığı zaman o kullanıcıyı bulunduğu tüm kanallardan uzaklaştırır.


on !*:join:#: { 
  if ($hmatch(#,$+($site,*),0) >= 2) { 
    kntrl # $site $nick 
  } 
  hadd -m # $+($site,½,$nick) 1 
}
alias kntrl { 
  var %1 1,%2 
  while ($hmatch($1,$+($2,*),%1)) {
    var %& = $gettok($v1,2,189) 
    if (%& != $3) { 
      %2 = $addtok(%2,%&,32) 
    } 
    inc %1 
  } 
  $iif($gettok(%2,2,32),echo $colour(join) -t $1 *** Bilgi: $3 nick'i daha önce; %2 nicklerinden giriş yaptı.)
}
Bu kod kanala giren nicklerin, daha önce hangi nick'lerden giriş yaptığını gösterir.



on *:snotice:*client connect*: {
  $iif(!$window(@giris),window -Cnak0 @giris) 
  echo $colour(info) -t @giris Giriş yaptı: $+($chr(40),$9,$chr(41))
}
on ^*:hotlink:(*):@giris:if ($left($1,1) == $chr(40)) return | else return
on *:hotlink:*:@giris:gline $remove($1,$chr(40),$chr(41)) :gline sebebi.
Bu kod sunucuya giren kullanıcıları ayrı sayfada gösterir (@giris). Ve o ayrı sayfadaki nick üzerine tıkladığınızda o kişiyi sunucudan uzaklaştırır (/gline)

on ^!*:join:#:haltdef | set %& # | .enable #j | userip $nick
#j off
raw 340:*: {
  haltdef 
  var %n = $gettok($2,1,61) 
  echo $colour(join) -t %& *** Giriş: %n $+($chr(40),$gettok($2,2,43),$chr(41)) 
  .disable #j
}
#j end
Bu kod kanala giren kullanıcıya /userip uygulayıp aynı kanalda gerçek IP'sini göstermeye yarar. Bunu yapabilmek için IRCop flaglarına sahip olmalısınız.



on *:snotice:*: { 
  if *client connect* iswm $1- { 
    var %s = $remove($gettok($10,2,64),$chr(41)) | hadd -m ip $+($9,½,%s) 
    if $hmatch(ip,$+(*,%s),0) >= 2 {
      var %q 1,%qq,%qqq = $gettok($hmatch(ip,$+(*,%s),1),2,189) 
      while %q <= $hmatch(ip,$+(*,%s),0) { 
      %qq = $addtok(%qq,$gettok($hmatch(ip,$+(*,%s),%q),1,189),44) 
      inc %q 
    } 
    echo -at Bilgi: %qqq adresiden bağlantı kuranlar: %qq  } 
  } 
  if *client exiting* iswm $1- { 
    if ($hmatch(ip,$+(*,$remove($gettok($7,2,64),$chr(41))))) hdel ip $v1 
  }
}

Bu kod sunucuya giren kullanıcının IP adresine bakarak clone/klon taraması yapar ve bu tarama sonuçlarını /echo komutu ile aktif ekrana yansıtır.


on *:rawmode:#belirtilen-kanal: {
  if $left($1,1) = $chr(43) && $regex($right($1,-1),a|o|h) { 
    sajoin $2 #belirtilen-kanal2
  }
}
Bu kod belirtilen kanalda op/sop/halpfop vs. olan kullanıcıları belirlediğiniz diğer kanala otomatik /sajoin-lemeye yarayan koddur.


alias -l bn { 
  var %s = 1 
  while ($read(badnick.txt,%s)) { 
    if $+(*,$v1,*) iswm $2 { 
      hinc -m bn nk 1 
      ban -k $1 $2 2 sebeb. 
      break 
    } 

    inc %s 
  } 
}
alias tara {
  $iif($hget(bn),hfree bn) 
  echo -ae Badnick taraması başlatıldı. 
  var %1 = 1 
  while ($nick($active,%1)) { 
    bn $active $v1
    inc %1 
  } 
  echo -ae $active Toplam $+($chr(40),$iif(!$hget(bn,nk),0,$hget(bn,nk)),$chr(41)) badnick atıldı. 
}
Bu kod herhangi bir kanal penceresinde /tara komutunu uyguladığınızda, badnick.txt dosyasındaki verileri kanal rumuzlarının içinde tek tek arar. Arama işlemi sırasında yakalanan nickleri kanaldan uzaklaştırır ve işlem tamamlandığında kaç adet badnick-in atıldığını size yansıtır.


on *:snotice:*client connect*: {
  if ($left($9,-2) = $remove($gettok($10,1,64),$chr(40)) && $remove($11,[,]) = $left($9,-2)) { 
    gline $9 sebeb. 
  }
}
Bu kod sunucuya giren kullanıcının ident, nick ve fullnamesi birbirinin aynısı ise sunucudan gline ile uzaklaştırmak için yazılmıştır.



on *:join:#:if ($nick = $me) inc -eu2 %k
on *:text:*:?: {
  if %k {
    var %1 = $1-,%2 = 1 
    while $comchan($nick,%2) { 
      ban -k $v1 $nick 2 Yasaklı kelime: %1 
      inc %2 
    } 
  } 
}
Bu kod herhangi bir kanala girdiğinizde eğer 2 saniye içerisinde özelinize yazan olursa, bulunmuş olduğunuz tüm kanallardan banlamak için yazılmıştır.


menu @log {
  dclick:$iif($mouse.lb,logs $active $1,return) 
}
on *:keydown:@log:46: {
  var %1 = $sline(@log,1),%2 = $sline(@log,1).ln 
  if (%1) $iif($input(%1 log'unu silmek istediğiniz'den eminmisiniz?,y,Uyarı) = $true,sil %1 %2,halt)
}
alias logoku { 
  $iif(!$window(@Log),window -aCl15 @Log) 
  if $findfile($logdir,*,0) != 0 { 
    $findfile($logdir,*,0,aline -l @Log $nopath($1-)) 
  } 
}
alias logs { 
  var %1 = 1,%2 = $lines($+($logdir,$sline(@log,1))),%3 = $sline(@log,1) 
  loadbuf -rp @log $shortfn($logdir $+ %3) 
}
alias sil .remove -b $shortfn($+($logdir,$1)) | window -c @log | logoku
Bu kod varolan tüm logları mIRC Custom(@log) penceresinde list şeklinde listelemenize, okumanıza ve silmenize yarayacaktır. Çok hızlı çalışmakla beraber basit bir arayüze sahip işlem yapmak isterseniz, gayet uygundur. 

Kod kullanımı: /logoku 
Belirtilen logu açmak için, listdeki loglara çift tıklayın. 
Sectiğiniz logu silmek için listedeki loga tıklayıp, DEL tuşuna basmanız yeterli olacaktır.


on *:voice:#help: {
  if ($nick == $me) $+(.timer,$vnick,_voice) 1 60 ban -k # $vnick 2 sebeb.
}
on *:text:*:#help: {
  if ($timer($nick $+ _voice)) $+(.timer,$v1) off
}
Bu kod #help kanalında voice verdiğiniz bir kullanıcı eğer 60 saniye içerisinde herhangi bir veri yazmazsa kullanıcıyı kanaldan banlar.


on *:snotice:*did a /whois on you*: {
  inc %1  
  $iif(!$window(@whois),window -lCb @whois,aline 2 @whois $+(%1,-) $2 whois çekti.)
}
Size whois çeken kullanıcıları aynı bir pencerede(-l) listeleyen(aline) kod.


on *:join:#belirtilen-kanal:userip $nick
alias iptara { 
  if $hget(kayıt) { 
    var %o = 1 
    while %o <= $hget(kayıt,0).item { 
      if $gettok($hget(kayıt,%o).item,2,189) == $1 && $gettok($hget(kayıt,%o).item,1,189) != $2 { 
        $iif(!$window(@sonuc),window -nCbsa @sonuc) 
        echo -te @sonuc Bilgi: $gettok($hget(kayıt,%o).item,2,189) IP adresin'den daha önce; $gettok($hget(kayıt,%o).item,1,189) nick'i ile giriş yapıldı. 
      } 
      inc %o
    } 
  } 
}
raw *:*: {
  haltdef
  if ($numeric = 340) {
    set %ip $gettok($2,2,64) 
    who +h $gettok($2,2,64) 
    hadd -m kayıt $+($gettok($2,1,61),½,$gettok($2,2,64)) 
    iptara $gettok($2,2,64) $gettok($2,1,61) 
  }
  if ($numeric = 352) {
    hadd -m nick $6 1 
  }
  if ($numeric = 315) {
    var %& = 1,%&& 
    while %& <= $hget(nick,0).item { 
      %&& = $addtok(%&&,$hget(nick,%&).item,32) 
      inc %& 
    } 
    $iif(!$window(@IP),window -nCbsa @IP) 
    echo -t @IP Bilgi: %ip adresin'den bağlantı kuranlar: %&& 
    unset %ip 
    hfree nick 
  }
}
Belitilen kanala giren kullanıcıların IP numaralarını işleme alarak, daha önce sunucuya girip/girmediği gösteren detaylı bir kod.


menu channel {
  Loglar menüsü
  .# logu:kanal #
  .Özel logları:falan $$?="Log'unu okumak istediginiz nick'i giriniz:"
}
alias falan {
  if $findfile($logdir,$+($1,*),0) >= 1 { 
    var %1 = $v1
    $iif($input(Aradığınız nick için %1 adet veri bulundu açmak istiyormusunuz?,w) == $false,halt)
    var %2 = 1,%3 = $findfile($logdir,$+($1,*),0) 
    while %2 <= %3 { run $findfile($logdir,$+($1,*),%2) | inc %2 }
  }
  else { 
    var %/ = $1,%½ = $left($1,1)
    $iif($input(Aradığınız %/ nick'i için uygun kayıt bulunamadı. %½ harfi ile başlıyan loglar listelensinmi?,w) == $false,halt)
    echo -at $left($1,1) ile başlıyan loglar sıralanıyor.
    echo -at $findfile($logdir,$+($left($1,1),*),0,echo -at $gettok($1-,$numtok($1-,92),92)) 
  }
}
alias kanal {
  if $findfile($logdir,$+($1,*),0) >= 1 {
    var %1 = $v1, %% = $1
    $iif($input(Aradığınız %% kanal'ı için %1 adet veri bulundu açmak istiyormusunuz?,w) == $false,halt)
    var %2 = 1,%3 = $findfile($logdir,$+($1,*),0) 
    while %2 <= %3 { 
      run $findfile($logdir,$+($1,*),%2) 
      inc %2 
    }
  }
  else {  
    var %& = $1 
    $input(%& kanal'ı için herhangi bir kayıt bulunamadı,ohud,UYARI,) 
  }
}
Bu kod kanal veya özel loglarını aramak/okumak vb. işlemler için yazılmış detaylı bir snippet-dır.


on *:text:*:?: {
  inc -e $+(%,t,$nick) 
  if $($+(%,t,$nick),2) == 1 { 
    .enable #u 
    .who $nick 
  } 
  else {
    var %1 = 1,%2 = $lines(kufur.txt) 
    while %1 <= %2 { 
      if $+(*,$read(kufur.txt,%1),*) iswm $1- && $hmatch(nick,$nick) {
        var %p = $nick 
      } 
      inc %1 
    } 
    var %s = 1,%ss = $comchan($me,0) 
    while %s <= %ss { 
      if $nick ison $comchan($me,%s) { 
        ban -ku900 $comchan($me,%s) %p 2 BAN SEBEBİ.
      } 
      inc %s 
    } 
  } 
}
#u off
raw *:*: { 
  if $numeric == 352 { 
    if r !isincs $7 { 
      haltdef 
      hadd -m nick $6 1 
    } 
  } 
  if $numeric == 315 {
    haltdef 
    .disable #u 
  } 
}
#u end
Bu kod özele yazan nick kayıtlı değilse ve kufur.txt dosyasından herhangi bir kelimeyi kullandıysa, tüm kanallardan banlamak için kullanılır.



umarım alıntı yaptığım parça kodlar işinize yarar. 
Sayın ziyaretçi, siteyi kayıtsız bir kullanıcı olarak görüntülüyorsunuz. Siteye kayıt olarak gezinti deneyiminizi olumlu yönde arttırabilirsiniz.

!banla rumuz sebep

!banla rumuz sebep

!banla <rumuz> <sebep>Kullanım

mIRC Scripting » mIRC Hazır Kodlar

2-08-2018, 10:27

Türkçe mIRC Karater Sorunu

Türkçe mIRC Karater Sorunu

Türkçe mIRC Karater Sorunu ve ÇözümüTavsiye :mIRC

mIRC Scripting » mIRC Hazır Kodlar

3-08-2018, 10:34
Adınız: *
E-Posta adresiniz: *
Resimde gösterilen iki kelimeyi girin: